Else

IF-서술문이 FALSE로 평가되면 수행할 멸령어를 지정합니다. 하나 이상의 명령어가 존재하면, 블록 안에 (활괄호) 싸 넣으십시오.

Else

ELSE를 사용하면 바로 위의 IF-서술문에 속합니다 (연관됩니다). ELSE는 언제나 위쪽으로 가장 가까운 IF-서술문에 속합니다. 단, 블록을 사용하여 그 행위를 바꾼 경우는 제외합니다.

ELSE 다음에 바로 같은 줄에 명령어 하나가 따라올 수 있습니다. 이것은 "else if" 사다리에 가장 많이 사용됩니다 (아래의 예제를 참조하십시오).

IF 또는 ELSE가 한 줄 이상을 소유하면, 그런 줄은 활괄호로 둘러 싸야 합니다. 그렇지만, 한 줄만 IF 또는 ELSE에 속해 있다면, 활괄호는 선택적입니다. 예를 들어:

if count > 0  ; 다음 줄에 괄호가 필요 없습니다. 왜냐하면 한 줄만 있기 때문입니다.
    MsgBox 프로세스를 시작하려면 OK를 누르십시오.
else  ; 아래 섹션에는 활괄호를 반드시 둘러야 합니다. 왜냐하면 한 줄 이상으로 구성되어 있기 때문입니다.
{
    WinClose Untitled - Notepad
    MsgBox 항목이 하나도 없습니다.
}

One True Brace (OTB) 스타일은 선택적으로 "else" 둘레에 사용할 수 있습니다. 예를 들어:

if IsDone {
    ...
} else if (x < y) {
    ...
} else {
    ...
}

Blocks 참조. 또, IF-명령어마다 ELSE를 사용할 수 있습니다. 여기에는 IfWinActive, IfWinExist, IfMsgBox, IfInString, IfBetween, IfIn, IF, 그리고 IF (expression)가 포함됩니다.

IfWinExist, Untitled - Notepad
{
    WinActivate
    Send This is a test.{Enter}
}
else
{
    WinActivate, Some Other Window
    MouseClick, left, 100, 200
}

if x = 1
    Gosub, a1
else if x = 2 ; "else if" 스타일
    Gosub, a2
else IfEqual, x, 3 ; 대안 스타일
{
    Gosub, a3
    Sleep, 1
}
else Gosub, a4  ; 즉, 명령어가 하나만 있으면  ELSE와 같은 줄에 있을 수 있습니다.
 
; Also OK:
IfEqual, y, 1, Gosub, b1
else {
    Sleep, 1
    Gosub, b2
}